راه اندازی ماژول NEO 7M

ماژول NEO 7M از سری ماژول های موقعیت یاب شرکت Ublox می باشد . این ماژول با وجود یک هسته GNSS از سیستم های GPS ، QZSS و GLONASS پشتیبانی می کند . یکی از مزیت های مهم ماژول های Ublox رابط ارتباطی ساده و نیز پشتیبانی آن در برنامه ها و پلتفرم های عرضه شده توسط Ublox می باشد . NEO 7M قابلیت تازه سازی دیتا با سرعت 10Hz را دارد که می توانید از آن در ربات ها و یا وسیله هایی که با سرعت حرکت می کنند استفاده کنید . این ماژول همچنین دارای یک حافظه جهت ذخیره تنظیمات است . همچنین می توانید یک باتری پشتیبان به آن متصل کنید تا مقادیر زمان را به صورت دقیق ذخیره کند . ماژول های GPS کاربرد فراوانی در سیستم های حمل و نقل عمومی ، ربات های پرنده و.. دارند . از خروجی های ماژول های GPS می توانید جهت مسیر یابی یا پیدا کردن موقعیت استفاده کنید . ماژول NEO 7M دارای یک رابط UART است که تنها دو پین از MCU را به خود اختصاصمی دهد . همچنین دارای یک رابط USB می باشد که می توانید آن را مستقیما به کامپیوتر متصل کرده و دیتای خروجی آن را ذخیره کنید یا بر روی نقشه نشان دهید . بر روی برد ماژول NEO 7M یک سوکت IPC جهت اتصال آنتن وجود دارد که می توانید آنواع مختلف آنتن های GPS را به آن متصل کنید .

در تصویر زیر پایه های مازول NEO 7M نشان داده شده است :

V

پایه VCC و GND پین های تغذیه ماژول می باشند .

RX و TX نیز جهت ارتباط UART هستند .

راه اندازی ماژول NEO 7M با آردوینو :

برای راه اندازی این ماژول می توانید از واحد UART یا از سریال نرم افزاری استفاده کنید .

#include <TinyGPS++.h>
#include <SoftwareSerial.h>
/*
   This sample sketch demonstrates the normal use of a TinyGPS++ (TinyGPSPlus) object.
   It requires the use of SoftwareSerial, and assumes that you have a
   9600-baud serial GPS device hooked up on pins 4(rx) and 3(tx).
*/
static const int RXPin = 4, TXPin = 3;
static const uint32_t GPSBaud = 9600;

// The TinyGPS++ object
TinyGPSPlus gps;

// The serial connection to the GPS device
SoftwareSerial ss(RXPin, TXPin);

void setup()
{
  Serial.begin(115200);
  ss.begin(GPSBaud);

  Serial.println(F("DeviceExample.ino"));
  Serial.println(F("A simple demonstration of TinyGPS++ with an attached GPS module"));
  Serial.print(F("Testing TinyGPS++ library v. ")); Serial.println(TinyGPSPlus::libraryVersion());
  Serial.println(F("by Mikal Hart"));
  Serial.println();
}

void loop()
{
  // This sketch displays information every time a new sentence is correctly encoded.
  while (ss.available() > 0)
    if (gps.encode(ss.read()))
      displayInfo();

  if (millis() > 5000 && gps.charsProcessed() < 10)
  {
    Serial.println(F("No GPS detected: check wiring."));
    while(true);
  }
}

void displayInfo()
{
  Serial.print(F("Location: ")); 
  if (gps.location.isValid())
  {
    Serial.print(gps.location.lat(), 6);
    Serial.print(F(","));
    Serial.print(gps.location.lng(), 6);
  }
  else
  {
    Serial.print(F("INVALID"));
  }

  Serial.print(F("  Date/Time: "));
  if (gps.date.isValid())
  {
    Serial.print(gps.date.month());
    Serial.print(F("/"));
    Serial.print(gps.date.day());
    Serial.print(F("/"));
    Serial.print(gps.date.year());
  }
  else
  {
    Serial.print(F("INVALID"));
  }

  Serial.print(F(" "));
  if (gps.time.isValid())
  {
    if (gps.time.hour() < 10) Serial.print(F("0"));
    Serial.print(gps.time.hour());
    Serial.print(F(":"));
    if (gps.time.minute() < 10) Serial.print(F("0"));
    Serial.print(gps.time.minute());
    Serial.print(F(":"));
    if (gps.time.second() < 10) Serial.print(F("0"));
    Serial.print(gps.time.second());
    Serial.print(F("."));
    if (gps.time.centisecond() < 10) Serial.print(F("0"));
    Serial.print(gps.time.centisecond());
  }
  else
  {
    Serial.print(F("INVALID"));
  }

  Serial.println();  }