راه اندازی شیلد LCD آردوینو

راه اندازی شیلد LCD آردوینو

استفاده از LCD در پروژهای امببد کار رایجی است . با اسفاده از نمایشگر ها برنامه می تواند با کاربر تعامل داشته باشد . شیلد LCD آردوینو یکی از جذاب ترین و کاربردی ترین شیلد های آردوینو به شمار می آید . در بسیاری از پروژه ها برای مانیتور کردن پارامتر های مختلف از این شیلد استفاده می شود . در این شیلد از یک LCD کاراکتری 2×16 استفاده شده است . این شیلد علاوه بر LCD ، شامل 6 کلید است که می توان از آن ها برای ساخت رابط کاربری و منو استفاده نمود . نکته جالب راجب به این شیلد این است که کلید های آن تنها از طریق یک پین کنترل می شودند !

 

در این شیلد پین های LCD به صورت زیر به پین های آردوینو متصل اند :

در این شیلد پین 10 آردوینو از طریق یک مدار ترانزیستوری به بک لایت LCD متصل است لذا امکان کنترل بک لایت در این شیلد وجود دارد .

 

 

راه اندازی شیلد LCD :

در راه اندازی LCD این شیلد می توان از کتابخانه L استفاده کرد . همچنین کلید های این ماژول هر کدام از طریق یک مقاومت به پین A0 آردوینو متصل اند . با فشردن هرکدام از کلید ها ولتاژ خاص آن کلید بر روی A0 قرار می گیرد لذا برای استفاده از کلید های این شیلد از واحد ADC استفاده می شود .

 

قبل از هر چیز لازم است که هدر فایل زیر را به برنامه خود اضافه کیند  :

#include <LiquidCrystal.h>

پس از فراخوانی کتابخانه باید از LiquidCrystal یک شی بسازید :

LiquidCrystal lcd(8, 9, 4, 5, 6, 7);

lcd اسم شی ساخته شده است که می تواند هر اسمی باشد . اعداد داخل پرانتز نیز پین هایی از آردوینو هستند که به LCD متصل اند .

 

حال با استفاده از متد begin می توانید LCD را پیکربندی کنید :

lcd.begin(16, 2);

پس از مراحل فوق می توانید از تولع زیر برای راه اندازی LCD شیلد استفاده کنید :

از دستور زیر برای قرار دان مکان نما استفاده می شود . موقعیت به صورت اول x و سپس y به تابع داده می شود .

lcd.setCursor(0,0);

از تابع زیر برای چاپ متن در مختصات مکان نما استفاده می شود :

lcd.print("متن");

باید حتما قبل ار اجرای دستور print با استفاده از تابع setCursor موقعیت مکان نما را تعیین کرد .

 

دستورات زیادی برای راه اندازی LCD های کاراکتری در کتابخانه LiquidCrystal وجود دارد . دستورات فوق تنها دستورات کاربردی و مهم این کتابخانه هستند .

 

در مثال زیر با فشردن هر کدام از کلید های شیلد LCD ، مقدار آن نمایش داده می شود :

//Sample using LiquidCrystal library
#include <LiquidCrystal.h>

/*******************************************************

This program will test the LCD panel and the buttons
Mark Bramwell, July 2010

********************************************************/

// select the pins used on the LCD panel
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);

// define some values used by the panel and buttons
int lcd_key     = 0;
int adc_key_in  = 0;
#define btnRIGHT  0
#define btnUP     1
#define btnDOWN   2
#define btnLEFT   3
#define btnSELECT 4
#define btnNONE   5

// read the buttons
int read_LCD_buttons()
{
 adc_key_in = analogRead(0);      // read the value from the sensor
 // my buttons when read are centered at these valies: 0, 144, 329, 504, 741
 // we add approx 50 to those values and check to see if we are close
 if (adc_key_in > 1000) return btnNONE; // We make this the 1st option for speed reasons since it will be the most likely result
 // For V1.1 us this threshold
 if (adc_key_in < 50)   return btnRIGHT;
 if (adc_key_in < 250)  return btnUP;
 if (adc_key_in < 450)  return btnDOWN;
 if (adc_key_in < 650)  return btnLEFT;
 if (adc_key_in < 850)  return btnSELECT;

 // For V1.0 comment the other threshold and use the one below:
/*
 if (adc_key_in < 50)   return btnRIGHT;
 if (adc_key_in < 195)  return btnUP;
 if (adc_key_in < 380)  return btnDOWN;
 if (adc_key_in < 555)  return btnLEFT;
 if (adc_key_in < 790)  return btnSELECT;
*/


 return btnNONE;  // when all others fail, return this...
}

void setup()
{
 lcd.begin(16, 2);              // start the library
 lcd.setCursor(0,0);
 lcd.print("Push the buttons"); // print a simple message
}

void loop()
{
 lcd.setCursor(9,1);            // move cursor to second line "1" and 9 spaces over
 lcd.print(millis()/1000);      // display seconds elapsed since power-up


 lcd.setCursor(0,1);            // move to the begining of the second line
 lcd_key = read_LCD_buttons();  // read the buttons

 switch (lcd_key)               // depending on which button was pushed, we perform an action
 {
   case btnRIGHT:
     {
     lcd.print("RIGHT ");
     break;
     }
   case btnLEFT:
     {
     lcd.print("LEFT   ");
     break;
     }
   case btnUP:
     {
     lcd.print("UP    ");
     break;
     }
   case btnDOWN:
     {
     lcd.print("DOWN  ");
     break;
     }
   case btnSELECT:
     {
     lcd.print("SELECT");
     break;
     }
     case btnNONE:
     {
     lcd.print("NONE  ");
     break;
     }
 }

}

 

از برنامه زیر نیز می توانید برای تست بک لایت LCD شیلد استفاده کنید :

void setup() {
pinMode(10,OUTPUT);
}
int i=0;
void loop() {
for(int y=0;y<256;y++)
{
 analogWrite(10,y); 
 delay(10);
}
for(int y=256;y--;)
{
 analogWrite(10,y); 
 delay(10);
}
}