اترنت یکی از راه های ارتباط بین کامپیوتر ها در شبکه های LAN است . این فناوری مبتنی بر Frame می باشد در واقع دیتا به صورت سریال و در قالب کاراکتر هایی ما بین کامپیوتر ها منتقل می گردد . در ارتباط اترنت از سوکت RJ45 و کابل های زوج به هم تابیده استفاده می شود . این شیلد بر پایه چیپ W5100 است که امکان ارتباط میکروکنترلر با شبکه را فراهم می کند . این شیلد دارای سوکت RJ45 می باشد که به راحتی می توان کابل های موسوم به کابل شبکه را به آن وصل کرد . همچنین این شیلد دارای یک اسلات SD کارت است که می توان از آن برای ذخیره دیتا و… استفاده کرد . این شیلد ارتباط آردوینو با اینترنت و شبکه های محلی را فراهم می سازد . ارتباط آردوینو با چیپ W5100 و SD کارت به صورت SPI است. می توان از این شیلد در پروژه های اینترنت اشیاء و همچنین دیتالاگر ها استفاده نمود .

نکته : چیپ W5100 در زمان فعالیت دارای دمای کاری بالایی می باشد . بهتر است از یک هیت سینک جهت خنک کردن آن استفاده کنید .

مشخصات :

دارای چیپ W5100 برای ارتباط با شبکه

دارای اسلات SD کارت

امکان نصب بر روی آردوینو UNO و MEGA

دارای سوکت RJ45 دارای

7 LED برای نمایش اتصال به شبکه ، ارسال ، دریافت و…

 

از شیلد اترنت می توان در پروژه های صنعتی و اینترنت اشیا استفاده نمود . به طور همزمان نمی توانید از شیلد LCD کاراکتری و شیلد اترنت استفاده کنید . برای این کار نیاز به تغییر سخت افزاری شیلد LCD خواهید داشت .

 

کد های راه اندازی توسط آردوینو :

شیلد اترنت را بر روی برد آردوینوی خود قرار دهید و آن را از طریق یک کابل شبکه به مودم خود متصل کنید . در این حالت کامیوتر شما باید از طریق وایفای یا کابل شبکه به همان مودم متصل باشد . سپس در محیط Serial monitor آردوینو IDE مقدار IP برد نشان داده می شود . این IP در مرورگر خود سرچ کنید .

 

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
IPAddress ip(192, 168, 1, 177);

// Initialize the Ethernet server library
// with the IP address and port you want to use
// (port 80 is default for HTTP):
EthernetServer server(80);

void setup() {
  // You can use Ethernet.init(pin) to configure the CS pin
  //Ethernet.init(10);  // Most Arduino shields
  //Ethernet.init(5);   // MKR ETH shield
  //Ethernet.init(0);   // Teensy 2.0
  //Ethernet.init(20);  // Teensy++ 2.0
  //Ethernet.init(15);  // ESP8266 with Adafruit Featherwing Ethernet
  //Ethernet.init(33);  // ESP32 with Adafruit Featherwing Ethernet

  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }
  Serial.println("Ethernet WebServer Example");

  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);

  // Check for Ethernet hardware present
  if (Ethernet.hardwareStatus() == EthernetNoHardware) {
    Serial.println("Ethernet shield was not found.  Sorry, can't run without hardware. :(");
    while (true) {
      delay(1); // do nothing, no point running without Ethernet hardware
    }
  }
  if (Ethernet.linkStatus() == LinkOFF) {
    Serial.println("Ethernet cable is not connected.");
  }

  // start the server
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}


void loop() {
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    bool currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println("client disconnected");
  }
}

 

 

Tags:
About Author: USER_4